Ian & Stuart's Australian Mac 1993 September/September 93.iso/Archives/Comunications/telecom/Telecom Utilities/CTB Modem Tools/CEPT Modem Tool/CEPT Modem Tool.rsrc/TEXT_20000_Hayes 1200_2400.txt

Text File | 1992-11-20 | 2.3 KB | 171 lines

! Default Hayes Script - 06 June 1992
!
@ORIGINATE
@ANSWER
!
@LABEL 1
serreset 2400, 0, 8, 1
!
! Load Factory configurations
!
@LABEL 2
matchclr
matchstr 1 3 "OK\13\10"
write "AT&F\13"
matchread 40
jump 59
!
!    Set up the configuration:
!    Echo off
!
@LABEL 3
matchstr 1 4 "OK\13\10"
write "ATE0\13"
matchread 30
jump 59
!
! Next, reset on DTR transition, set direct mode
!
@LABEL 4
matchstr 1 5 "OK\13\10"
write "AT&D3\13"
matchread 30
jump 59

@LABEL 5
matchstr 1 6 "\13\10"
write "AT\\N0\13"
matchread 30
jump 59
!
! If speaker on flag is true, jump to label 8.  Else turn off the speaker
!
@LABEL 6
ifstr 2 8 "1"
note "Speaker Off"
pause 10
matchstr 1 8 "OK"
write "ATM0\13"
matchread 30
jump 59
!
! The modem is ready so enable answering, or originate a call
!
@LABEL 8
pause 10
ifANSWER 30
!
! @ORIGINATE
!
note "Dialing ^1" 3
write "ATD^1\13"
!
@LABEL 9
JSR 80
matchread 700
jump 59
!
!
! @ANSWER
! Set up the modem to answer
@LABEL 30
write "ATS0=1\13"
matchstr 1 31 "OK\13\10"
matchread 30
jump 59
!
@LABEL 31
jsr 80
matchstr 16  32 "RING\13\10"
matchread 700
jump 31
!
@LABEL 32
userhook 1
note "Answering phone…" 2
jump 31
!
! Standard responses
!
@LABEL 80
matchclr
matchstr 1 11 "CONNECT 1200\13\10"
matchstr 2 12 "CONNECT 2400\13\10"
matchstr 3 50 "NO CARRIER\13\10"
matchstr 4 50 "ERROR\13\10"
matchstr 5 52 "NO DIALTONE\13\10"
matchstr 6 53 "BUSY\13\10"
matchstr 7 54 "NO ANSWER\13\10"
return
!
! Connection established
!
@LABEL 11
note "Communicating at 1200 bps." 2
CommunicatingAt 1200
jump 15
!
@LABEL 12
note "Communicating at 2400 bps." 2
CommunicatingAt 2400
!
@LABEL 15
ifANSWER 16
pause 20
@LABEL 16
exit 0
!
! 50: error messages
! No carrier
@LABEL 50
exit -6021
! No Dial Tone
@LABEL 52
exit -6020
! Busy
@LABEL 53
exit -6022
! No Answer
@LABEL 54
exit -6023
! Modem error
@LABEL 59
exit -6019
!
! Hang up the modem
!
@HANGUP
Note "Disconnecting…"
@LABEL 60
settries 0
@LABEL 61
write "ATH0\13"
matchclr
matchstr 1 62 "\13\10NO CARRIER\13\10"
matchstr 2 62 "OK\13\10"
matchstr 3 62 "ERROR\13\10"
matchread 30
inctries
iftries 3 62
! no response, try escape sequence
write "+++"
matchclr
matchstr 1 61 "OK\13\10"
matchread 15
! try dropping DTR
DTRClear
pause 10
DTRSet
pause 10
jump 61
!
! Recall the factory settings
!
@LABEL 62
write "AT&F\13"
matchclr
matchstr 1 63 "OK\13\10"
matchread 30
!
@LABEL 63
exit 0